How to integrate all language packs into Windows 7

If you'd like to add more languages or all languages to your Windows 7 deployment image this can be done by hand or with below script. This script requires some path configurations only and integrates all lp.cab files from the Microsoft Language Pack DVD.

Required:

  • Windows Automated Installation Kit (AIK)
  • Microsoft Windows 7 Enterprise DVD
  • Microsoft Windows 7 Language Pack DVD

Steps:

  1. Copy install.wim from Windows 7 DVD \sources\install.wim to local disk
  2. Configure path to language packs. This is folder named langpacks with subfolders named "ar-sa", "de-de" and so on.
  3. Configure all other paths
  4. Run the batch file to integrate all Language Packs (may take some hours/one day).
  5. Add this WMI file to your Windows Deployment Server (WDS).

Script:

@ECHO OFF
REM Build a single WMI file with all available languages for Enterprise Deployment 
 
SET LANGPACKS=F:\langpacks
SET MOUNTDIR=C:\Mount
SET SCRATCHDIR=C:\Scratch
SET WIM=C:\Temp\Windows 7\Enterprise\x64\install.wim
SET WIMINFO=Windows 7 ENTERPRISE
 
mkdir "%MOUNTDIR%"
mkdir "%SCRATCHDIR%"
 
dism /Mount-WIM /WimFile:"%WIM%" /Name:"%WIMINFO%" /MountDir:"%MOUNTDIR%"
 
FOR /F " usebackq" %%i IN (`dir /b "%LANGPACKS%"`) DO (
  dism /Image:"%MOUNTDIR%" /ScratchDir:"%SCRATCHDIR%" /Add-Package /PackagePath:"%LANGPACKS%\%%i\lp.cab"
  dism /Image:"%MOUNTDIR%" /get-Intl
)
 
dism /Unmount-WIM /MountDir:"%MOUNTDIR%" /Commit

REM Configure German langague pack as default
dism /Image:"%MOUNTDIR%" /Set-SKUIntlDefaults:de-de

REM Configure default language for UI, System Locale
dism /image:"%MOUNTDIR%" /Set-AllIntl:de-de
 
SET LANGPACKS=
SET MOUNTDIR=
SET SCRATCHDIR=
SET WIM=
SET WIMINFO=
Bewertung: 
Noch keine Bewertungen vorhanden